Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/xml/folds.scm

@@ -0,0 +1,5 @@
+[
+  (element)
+  (doctypedecl)
+  (Comment)
+] @fold

config/neovim/store/nvim-treesitter/queries/xml/highlights.scm

@@ -0,0 +1,66 @@
+; inherits: dtd
+
+; XML declaration
+(XMLDecl
+  "standalone" @tag.attribute)
+
+(XMLDecl
+  [
+    "yes"
+    "no"
+  ] @boolean)
+
+; Processing instructions
+(XmlModelPI
+  "xml-model" @keyword.directive)
+
+(StyleSheetPI
+  "xml-stylesheet" @keyword.directive)
+
+(PseudoAtt
+  (Name) @tag.attribute)
+
+(PseudoAtt
+  (PseudoAttValue) @string)
+
+; Doctype declaration
+(doctypedecl
+  "DOCTYPE" @keyword.directive.define)
+
+(doctypedecl
+  (Name) @type.definition)
+
+; Tags
+(STag
+  (Name) @tag)
+
+(ETag
+  (Name) @tag)
+
+(EmptyElemTag
+  (Name) @tag)
+
+; Attributes
+(Attribute
+  (Name) @tag.attribute)
+
+(Attribute
+  (AttValue) @string)
+
+; Text
+(CharData) @none @spell
+
+((CDSect
+  (CDStart) @module
+  (CData) @markup.raw
+  "]]>" @module)
+  (#set! "priority" 105))
+
+; Delimiters & punctuation
+[
+  "<"
+  "</"
+  "/>"
+] @tag.delimiter
+
+"]" @punctuation.bracket

config/neovim/store/nvim-treesitter/queries/xml/indents.scm

@@ -0,0 +1,16 @@
+(element) @indent.begin
+
+[
+  (Attribute)
+  (AttlistDecl)
+  (contentspec)
+] @indent.align
+
+(ETag) @indent.dedent
+
+(doctypedecl) @indent.ignore
+
+[
+  (Comment)
+  (ERROR)
+] @indent.auto

config/neovim/store/nvim-treesitter/queries/xml/injections.scm

@@ -0,0 +1,32 @@
+((Comment) @injection.content
+  (#set! injection.language "comment"))
+
+; SVG style
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "style")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "css"))
+
+; SVG script
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "script")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "javascript"))
+
+; phpMyAdmin dump
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "pma:table")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "sql"))

config/neovim/store/nvim-treesitter/queries/xml/locals.scm

@@ -0,0 +1,35 @@
+; tags
+(elementdecl
+  (Name) @local.definition.type)
+
+(elementdecl
+  (contentspec
+    (children
+      (Name) @local.reference)))
+
+(AttlistDecl
+  .
+  (Name) @local.reference)
+
+(STag
+  (Name) @local.reference)
+
+(ETag
+  (Name) @local.reference)
+
+(EmptyElemTag
+  (Name) @local.reference)
+
+; attributes
+(AttDef
+  (Name) @local.definition.field)
+
+(Attribute
+  (Name) @local.reference)
+
+; entities
+(GEDecl
+  (Name) @local.definition.macro)
+
+(EntityRef
+  (Name) @local.reference)