Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/udev/highlights.scm

@@ -0,0 +1,67 @@
+(match
+  key: _ @keyword)
+
+(assignment
+  key: _ @property)
+
+(value) @string
+
+; NOTE: higher priorities override bash highlights
+((fmt_sub
+  .
+  _ @character.special)
+  (#set! "priority" 101))
+
+((var_sub
+  .
+  _ @variable.builtin)
+  (#set! "priority" 101))
+
+[
+  (system_const)
+  (run_type)
+  (import_type)
+  (kernel_param)
+  (seclabel)
+] @attribute
+
+((attribute) @attribute
+  (#set! "priority" 101))
+
+((env_var) @constant
+  (#set! "priority" 101))
+
+((pattern) @string.special
+  (#set! "priority" 101))
+
+([
+  "\\\""
+  (c_escape)
+] @string.escape
+  (#set! "priority" 101))
+
+(octal) @number
+
+((number) @number
+  (#set! "priority" 101))
+
+[
+  (match_op)
+  (assignment_op)
+] @operator
+
+("+" @punctuation.special
+  (#set! "priority" 101))
+
+([
+  "{"
+  "}"
+] @punctuation.bracket
+  (#set! "priority" 101))
+
+[
+  ","
+  (linebreak)
+] @punctuation.delimiter
+
+(comment) @comment @spell

config/neovim/store/nvim-treesitter/queries/udev/injections.scm

@@ -0,0 +1,14 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((match
+  key: "PROGRAM"
+  (value
+    (content) @injection.content))
+  (#set! injection.language "bash"))
+
+((assignment
+  key: "RUN"
+  (value
+    (content) @injection.content))
+  (#set! injection.language "bash"))

config/neovim/store/nvim-treesitter/queries/udev/locals.scm

@@ -0,0 +1,29 @@
+; labels
+(assignment
+  key: "LABEL"
+  (value
+    (content) @local.definition))
+
+(assignment
+  key: "GOTO"
+  (value
+    (content) @local.reference))
+
+; env vars
+(assignment
+  key: "ENV"
+  (env_var) @local.definition.var)
+
+(match
+  key: "ENV"
+  (env_var) @local.reference)
+
+(var_sub
+  (env_var) @local.reference)
+
+; misc
+[
+  (attribute)
+  (kernel_param)
+  (seclabel)
+] @local.reference