Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/svelte/folds.scm

@@ -0,0 +1,13 @@
+; inherits: html
+
+[
+  (if_statement)
+  (else_if_block)
+  (else_block)
+  (each_statement)
+  (await_statement)
+  (then_block)
+  (catch_block)
+  (key_statement)
+  (snippet_statement)
+] @fold

config/neovim/store/nvim-treesitter/queries/svelte/highlights.scm

@@ -0,0 +1,42 @@
+; inherits: html
+
+(raw_text) @none
+
+[
+  "as"
+  "key"
+  "html"
+  "snippet"
+  "render"
+] @keyword
+
+"const" @keyword.modifier
+
+[
+  "if"
+  "else"
+  "then"
+] @keyword.conditional
+
+"each" @keyword.repeat
+
+[
+  "await"
+  "then"
+] @keyword.coroutine
+
+"catch" @keyword.exception
+
+"debug" @keyword.debug
+
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "#"
+  ":"
+  "/"
+  "@"
+] @tag.delimiter

config/neovim/store/nvim-treesitter/queries/svelte/indents.scm

@@ -0,0 +1,34 @@
+; inherits: html
+
+[
+  (if_statement)
+  (each_statement)
+  (await_statement)
+  (key_statement)
+  (snippet_statement)
+] @indent.begin
+
+(if_end
+  "}" @indent.end)
+
+(each_end
+  "}" @indent.end)
+
+(await_end
+  "}" @indent.end)
+
+(key_end
+  "}" @indent.end)
+
+(snippet_end
+  "}" @indent.end)
+
+[
+  (if_end)
+  (else_if_block)
+  (else_block)
+  (each_end)
+  (await_end)
+  (key_end)
+  (snippet_end)
+] @indent.branch

config/neovim/store/nvim-treesitter/queries/svelte/injections.scm

@@ -0,0 +1,47 @@
+; inherits: html_tags
+
+((style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "scss" "postcss" "less")
+  (#set! injection.language "scss"))
+
+((svelte_raw_text) @injection.content
+  (#set! injection.language "javascript"))
+
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "ts" "typescript")
+  (#set! injection.language "typescript"))
+
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "js" "javascript")
+  (#set! injection.language "javascript"))
+
+((element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (text) @injection.content)
+  (#eq? @_attr "lang")
+  (#eq? @injection.language "pug"))

config/neovim/store/nvim-treesitter/queries/svelte/locals.scm

@@ -0,0 +1 @@
+; inherits: html