Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/supercollider/folds.scm

@@ -0,0 +1,6 @@
+[
+  (function_call)
+  (code_block)
+  (function_block)
+  (control_structure)
+] @fold

config/neovim/store/nvim-treesitter/queries/supercollider/highlights.scm

@@ -0,0 +1,103 @@
+; highlights.scm
+; See this for full list: https://github.com/nvim-treesitter/nvim-treesitter/blob/master/CONTRIBUTING.md
+; comments
+(line_comment) @comment @spell
+
+(block_comment) @comment @spell
+
+; Argument definition
+(argument
+  name: (identifier) @variable.parameter)
+
+; Variables
+(local_var
+  name: (identifier) @variable)
+
+(environment_var
+  name: (identifier) @variable.builtin)
+
+(builtin_var) @constant.builtin
+
+; (variable) @variable
+; Functions
+(function_definition
+  name: (variable) @function)
+
+; For function calls
+(named_argument
+  name: (identifier) @function.call)
+
+; Methods
+(method_call
+  name: (method_name) @function.method.call)
+
+; Classes
+(class) @type
+
+; Literals
+(number) @number
+
+(float) @number.float
+
+(string) @string
+
+(symbol) @string.special.symbol
+
+; Operators
+[
+  "&&"
+  "||"
+  "&"
+  "|"
+  "^"
+  "=="
+  "!="
+  "<"
+  "<="
+  ">"
+  ">="
+  "<<"
+  ">>"
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "="
+] @operator
+
+; Keywords
+[
+  "arg"
+  "classvar"
+  "const"
+  ; "super"
+  ; "this"
+  "var"
+] @keyword
+
+; Brackets
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "|"
+] @punctuation.bracket
+
+; Delimiters
+[
+  ";"
+  "."
+  ","
+] @punctuation.delimiter
+
+; control structure
+(control_structure) @keyword.conditional
+
+(escape_sequence) @string.escape
+
+; SinOsc.ar()!2
+(duplicated_statement) @keyword.repeat

config/neovim/store/nvim-treesitter/queries/supercollider/indents.scm

@@ -0,0 +1,33 @@
+[
+  (function_block)
+  (binary_expression)
+  (collection)
+  (indexed_collection)
+  (parameter_call_list)
+  (function_call)
+  (class_def)
+  (classvar)
+  (const)
+  (instance_var)
+  (variable_definition)
+  (variable_definition_sequence
+    (variable_definition))
+  (control_structure)
+  (return_statement)
+] @indent.begin
+
+[
+  (parameter_call_list
+    (argument_calls))
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @indent.branch
+
+[
+  (block_comment)
+  (line_comment)
+] @indent.ignore

config/neovim/store/nvim-treesitter/queries/supercollider/injections.scm

@@ -0,0 +1,5 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))

config/neovim/store/nvim-treesitter/queries/supercollider/locals.scm

@@ -0,0 +1,29 @@
+; Scopes
+[
+  (function_call)
+  (code_block)
+  (function_block)
+  (control_structure)
+] @local.scope
+
+; Definitions
+(argument
+  name: (identifier) @local.definition.parameter
+  (#set! "definition.var.scope" "local"))
+
+(variable_definition
+  name: (variable
+    (local_var
+      (identifier) @local.definition.var)))
+
+(variable_definition
+  name: (variable
+    (environment_var
+      (identifier) @local.definition.var))
+  (#set! "definition.var.scope" "global"))
+
+(function_definition
+  name: (variable) @local.definition.var
+  (#set! "definition.var.scope" "parent"))
+
+(identifier) @local.reference