Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/ssh_config/folds.scm

@@ -0,0 +1,4 @@
+[
+  (host_declaration)
+  (match_declaration)
+] @fold

config/neovim/store/nvim-treesitter/queries/ssh_config/highlights.scm

@@ -0,0 +1,106 @@
+; Literals
+(string) @string
+
+(pattern) @string.regexp
+
+(token) @character
+
+[
+  (number)
+  (bytes)
+  (time)
+] @number
+
+[
+  (kex)
+  (mac)
+  (cipher)
+  (key_sig)
+] @variable.parameter
+
+[
+  ; generic
+  "yes"
+  "no"
+  "ask"
+  "auto"
+  "none"
+  "any"
+  ; ControlMaster
+  "autoask"
+  ; FingerprintHash
+  "md5"
+  "sha256"
+  ; PubkeyAuthentication
+  "unbound"
+  "host-bound"
+  ; RequestTTY
+  "force"
+  ; SessionType
+  "subsystem"
+  "default"
+  ; StrictHostKeyChecking
+  "accept-new"
+  "off"
+  ; Tunnel
+  "point-to-point"
+  "ethernet"
+  (ipqos)
+  (verbosity)
+  (facility)
+  (authentication)
+] @constant.builtin
+
+(uri) @string.special.url
+
+; Keywords
+[
+  "Host"
+  "Match"
+] @keyword
+
+(parameter
+  keyword: _ @keyword)
+
+(host_declaration
+  argument: _ @module)
+
+(match_declaration
+  (condition
+    criteria: _ @attribute))
+
+"all" @attribute
+
+; Misc
+[
+  "SSH_AUTH_SOCK"
+  (variable)
+] @constant
+
+(comment) @comment @spell
+
+; Punctuation
+[
+  "${"
+  "}"
+] @punctuation.special
+
+[
+  "\""
+  ","
+  ":"
+  "@"
+] @punctuation.delimiter
+
+[
+  "="
+  "!"
+  "+"
+  "-"
+  "^"
+] @operator
+
+[
+  "*"
+  "?"
+] @character.special

config/neovim/store/nvim-treesitter/queries/ssh_config/indents.scm

@@ -0,0 +1,12 @@
+[
+  (host_declaration)
+  (match_declaration)
+] @indent.begin
+
+; incomplete declarations
+(ERROR
+  .
+  [
+    "Host"
+    "Match"
+  ]) @indent.begin

config/neovim/store/nvim-treesitter/queries/ssh_config/injections.scm

@@ -0,0 +1,17 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((condition
+  criteria: "exec"
+  argument: (string) @injection.content)
+  (#set! injection.language "bash"))
+
+((parameter
+  keyword: [
+    "KnownHostsCommand"
+    "LocalCommand"
+    "RemoteCommand"
+    "ProxyCommand"
+  ]
+  argument: (string) @injection.content)
+  (#set! injection.language "bash"))

config/neovim/store/nvim-treesitter/queries/ssh_config/locals.scm

@@ -0,0 +1,7 @@
+(parameter
+  keyword: "Tag"
+  argument: (string) @local.reference)
+
+(condition
+  criteria: "tagged"
+  argument: (pattern) @local.definition)