1

Regenerate nvim config

This commit is contained in:
2024-06-02 03:29:20 +02:00
parent 75eea0c030
commit ef2e28883d
5576 changed files with 604886 additions and 503 deletions

View File

@ -0,0 +1,5 @@
[
(enum)
(message)
(service)
] @fold

View File

@ -0,0 +1,82 @@
[
"extend"
"extensions"
"oneof"
"option"
"reserved"
"syntax"
"to"
] @keyword
[
"enum"
"service"
"message"
] @keyword.type
"rpc" @keyword.function
"returns" @keyword.return
[
"optional"
"repeated"
"required"
] @keyword.modifier
[
"package"
"import"
] @keyword.import
[
(key_type)
(type)
(message_name)
(enum_name)
(service_name)
(rpc_name)
(message_or_enum_type)
] @type
(enum_field
(identifier) @constant)
(string) @string
[
"\"proto3\""
"\"proto2\""
] @string.special
(int_lit) @number
(float_lit) @number.float
[
(true)
(false)
] @boolean
(comment) @comment @spell
((comment) @comment.documentation
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
[
"("
")"
"["
"]"
"{"
"}"
"<"
">"
] @punctuation.bracket
[
";"
","
] @punctuation.delimiter
"=" @operator