Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/kdl/folds.scm

@@ -0,0 +1,7 @@
+; Folds
+[
+  (node)
+  (node_children)
+  (string)
+  (multi_line_comment)
+] @fold

config/neovim/store/nvim-treesitter/queries/kdl/highlights.scm

@@ -0,0 +1,70 @@
+; Types
+(node
+  (identifier) @type)
+
+(type) @type
+
+(annotation_type) @type.builtin
+
+; Properties
+(prop
+  (identifier) @property)
+
+; Variables
+(identifier) @variable
+
+; Operators
+[
+  "="
+  "+"
+  "-"
+] @operator
+
+; Literals
+(string) @string
+
+(escape) @string.escape
+
+(number) @number
+
+(number
+  (decimal) @number.float)
+
+(number
+  (exponent) @number.float)
+
+(boolean) @boolean
+
+"null" @constant.builtin
+
+; Punctuation
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+";" @punctuation.delimiter
+
+; Comments
+[
+  (single_line_comment)
+  (multi_line_comment)
+] @comment @spell
+
+(node
+  (node_comment)
+  (#set! "priority" 105)) @comment
+
+(node
+  (node_field
+    (node_field_comment)
+    (#set! "priority" 105)) @comment)
+
+(node_children
+  (node_children_comment)
+  (#set! "priority" 105)) @comment

config/neovim/store/nvim-treesitter/queries/kdl/indents.scm

@@ -0,0 +1,14 @@
+(node
+  (node_children) @indent.begin)
+
+"}" @indent.end
+
+[
+  "{"
+  "}"
+] @indent.branch
+
+[
+  "("
+  ")"
+] @indent.branch

config/neovim/store/nvim-treesitter/queries/kdl/injections.scm

@@ -0,0 +1,5 @@
+([
+  (single_line_comment)
+  (multi_line_comment)
+] @injection.content
+  (#set! injection.language "comment"))

config/neovim/store/nvim-treesitter/queries/kdl/locals.scm

@@ -0,0 +1,16 @@
+(document) @local.scope
+
+(node
+  (node_children) @local.scope)
+
+(node_children
+  (node) @local.scope)
+
+(identifier) @local.reference
+
+(node_field) @local.definition.field
+
+(node
+  (identifier) @local.definition.type)
+
+(type) @local.definition.type