Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/kconfig/folds.scm

@@ -0,0 +1,9 @@
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+  (help_text)
+] @fold

config/neovim/store/nvim-treesitter/queries/kconfig/highlights.scm

@@ -0,0 +1,102 @@
+"source" @keyword.import
+
+[
+  "mainmenu"
+  "config"
+  "menuconfig"
+  "choice"
+  "endchoice"
+  "comment"
+  "menu"
+  "endmenu"
+  "prompt"
+  "default"
+  "range"
+  "help"
+  (optional)
+  (modules)
+] @keyword
+
+[
+  "if"
+  "endif"
+  "depends on"
+  "select"
+  "imply"
+  "visible if"
+] @keyword.conditional
+
+[
+  "def_bool"
+  "def_tristate"
+] @keyword.function
+
+[
+  "||"
+  "&&"
+  "="
+  "!="
+  "<"
+  ">"
+  "<="
+  ">="
+  "!"
+  ":="
+  "+="
+  "?="
+] @operator
+
+[
+  "bool"
+  "tristate"
+  "int"
+  "hex"
+  "string"
+] @type.builtin
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+"," @punctuation.delimiter
+
+(macro_variable
+  [
+    "$("
+    ")"
+  ] @punctuation.special)
+
+(symbol) @variable
+
+[
+  (prompt)
+  (macro_content)
+  (text)
+] @string
+
+(config
+  name: (symbol) @constant)
+
+(menuconfig
+  name: (symbol) @constant)
+
+(choice
+  name: (symbol) @constant)
+
+((symbol) @constant
+  (#lua-match? @constant "[A-Z0-9]+"))
+
+(mainmenu
+  name: (prompt) @markup.heading)
+
+(comment_entry
+  name: (prompt) @markup.heading)
+
+(menu
+  name: (prompt) @markup.heading)
+
+(source
+  (prompt) @string.special.url)
+
+(comment) @comment @spell

config/neovim/store/nvim-treesitter/queries/kconfig/indents.scm

@@ -0,0 +1,12 @@
+(help_text
+  (text) @indent.auto)
+
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+  (help_text)
+] @indent.begin

config/neovim/store/nvim-treesitter/queries/kconfig/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

config/neovim/store/nvim-treesitter/queries/kconfig/locals.scm

@@ -0,0 +1,24 @@
+[
+  (symbol)
+  (prompt)
+] @local.reference
+
+[
+  (config)
+  (menuconfig)
+  (choice)
+  (comment_entry)
+  (menu)
+  (if)
+] @local.scope
+
+(type_definition
+  (prompt) @local.definition.var)
+
+(type_definition
+  (input_prompt
+    (prompt) @local.definition.var))
+
+(type_definition_default
+  (expression
+    (prompt) @local.definition.var))