Regenerate nvim config

config/neovim/store/nvim-treesitter/queries/facility/folds.scm

@@ -0,0 +1,6 @@
+[
+  (service)
+  (method)
+  (dto)
+  (enum)
+] @fold

config/neovim/store/nvim-treesitter/queries/facility/highlights.scm

@@ -0,0 +1,87 @@
+[
+  ";"
+  "."
+  ","
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(comment) @comment @spell
+
+(doc_comment) @comment.documentation @spell
+
+[
+  "service"
+  "errors"
+] @keyword
+
+"method" @keyword.function
+
+[
+  "enum"
+  "data"
+] @keyword.type
+
+"extern" @keyword.modifier
+
+(type) @type.builtin
+
+(service
+  service_name: (identifier) @type)
+
+(error_set
+  (identifier) @variable.member)
+
+(error_set
+  name: (identifier) @type)
+
+(dto
+  name: (identifier) @type)
+
+(external_dto
+  name: (identifier) @type)
+
+(enum
+  (values_block
+    (identifier) @constant))
+
+(enum
+  name: (identifier) @type)
+
+(external_enum
+  name: (identifier) @type)
+
+(type
+  name: (identifier) @type)
+
+[
+  "map"
+  "nullable"
+  "result"
+  "required"
+  "http"
+  "csharp"
+  "js"
+  "info"
+  "obsolete"
+] @attribute.builtin
+
+(parameter
+  name: (identifier) @variable.parameter)
+
+(field
+  name: (identifier) @variable.member)
+
+(method
+  name: (identifier) @function.method)
+
+(number_literal) @number
+
+(string_literal) @string

config/neovim/store/nvim-treesitter/queries/facility/indents.scm

@@ -0,0 +1,7 @@
+[
+  (service_block)
+  (values_block)
+  (field_list)
+] @indent.begin
+
+"}" @indent.branch

config/neovim/store/nvim-treesitter/queries/facility/injections.scm

@@ -0,0 +1,8 @@
+((remarks) @injection.content
+  (#set! injection.language "markdown"))
+
+([
+  (comment)
+  (doc_comment)
+] @injection.content
+  (#set! injection.language "comment"))