Regenerate nvim config

config/neovim/store/lazy-plugins/nvim-treesitter/queries/yaml/folds.scm

@@ -0,0 +1,4 @@
+[
+  (block_mapping_pair)
+  (block_sequence_item)
+] @fold

config/neovim/store/lazy-plugins/nvim-treesitter/queries/yaml/highlights.scm

@@ -0,0 +1,82 @@
+(boolean_scalar) @boolean
+
+(null_scalar) @constant.builtin
+
+(double_quote_scalar) @string
+
+(single_quote_scalar) @string
+
+((block_scalar) @string
+  (#set! "priority" 99))
+
+(string_scalar) @string
+
+(escape_sequence) @string.escape
+
+(integer_scalar) @number
+
+(float_scalar) @number
+
+(comment) @comment @spell
+
+[
+  (anchor_name)
+  (alias_name)
+] @label
+
+(tag) @type
+
+[
+  (yaml_directive)
+  (tag_directive)
+  (reserved_directive)
+] @keyword.directive
+
+(block_mapping_pair
+  key: (flow_node
+    [
+      (double_quote_scalar)
+      (single_quote_scalar)
+    ] @property))
+
+(block_mapping_pair
+  key: (flow_node
+    (plain_scalar
+      (string_scalar) @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      [
+        (double_quote_scalar)
+        (single_quote_scalar)
+      ] @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      (plain_scalar
+        (string_scalar) @property))))
+
+[
+  ","
+  "-"
+  ":"
+  ">"
+  "?"
+  "|"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "*"
+  "&"
+  "---"
+  "..."
+] @punctuation.special

config/neovim/store/lazy-plugins/nvim-treesitter/queries/yaml/indents.scm

@@ -0,0 +1,7 @@
+[
+  (block_mapping_pair
+    value: (block_node))
+  (block_sequence_item)
+] @indent.begin
+
+(ERROR) @indent.auto

config/neovim/store/lazy-plugins/nvim-treesitter/queries/yaml/injections.scm

@@ -0,0 +1,80 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+; Github actions ("run") / Gitlab CI ("scripts")
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (flow_node
+    (plain_scalar
+      (string_scalar) @injection.content)
+    (#set! injection.language "bash")))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (block_node
+    (block_scalar) @injection.content
+    (#set! injection.language "bash")
+    (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (flow_node
+          (plain_scalar
+            (string_scalar) @injection.content))
+        (#set! injection.language "bash")))))
+
+(block_mapping_pair
+  key: (flow_node) @_run
+  (#any-of? @_run "script" "before_script" "after_script")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (block_node
+          (block_scalar) @injection.content
+          (#set! injection.language "bash")
+          (#offset! @injection.content 0 1 0 0))))))
+
+; Prometheus Alertmanager ("expr")
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (flow_node
+    (plain_scalar
+      (string_scalar) @injection.content)
+    (#set! injection.language "promql")))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_scalar) @injection.content
+    (#set! injection.language "promql")
+    (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (flow_node
+          (plain_scalar
+            (string_scalar) @injection.content))
+        (#set! injection.language "promql")))))
+
+(block_mapping_pair
+  key: (flow_node) @_expr
+  (#eq? @_expr "expr")
+  value: (block_node
+    (block_sequence
+      (block_sequence_item
+        (block_node
+          (block_scalar) @injection.content
+          (#set! injection.language "promql")
+          (#offset! @injection.content 0 1 0 0))))))

config/neovim/store/lazy-plugins/nvim-treesitter/queries/yaml/locals.scm

@@ -0,0 +1,9 @@
+[
+  (stream)
+  (document)
+  (block_node)
+] @local.scope
+
+(anchor_name) @local.definition
+
+(alias_name) @local.reference