Regenerate nvim config

config/neovim/store/lazy-plugins/nvim-treesitter/queries/turtle/folds.scm

@@ -0,0 +1,4 @@
+[
+  (statement)
+  (blank_node_property_list)
+] @fold

config/neovim/store/lazy-plugins/nvim-treesitter/queries/turtle/highlights.scm

@@ -0,0 +1,62 @@
+(string) @string
+
+(lang_tag) @type
+
+[
+  "_:"
+  "<"
+  ">"
+  (namespace)
+] @module
+
+[
+  (iri_reference)
+  (prefixed_name)
+] @variable
+
+(blank_node_label) @variable
+
+"a" @variable.builtin
+
+(integer) @number
+
+[
+  (decimal)
+  (double)
+] @number.float
+
+(boolean_literal) @boolean
+
+[
+  "BASE"
+  "PREFIX"
+  "@prefix"
+  "@base"
+] @keyword
+
+[
+  "."
+  ","
+  ";"
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  (anon)
+] @punctuation.bracket
+
+(comment) @comment @spell
+
+(echar) @string.escape
+
+(rdf_literal
+  "^^" @type
+  datatype: (_
+    [
+      "<"
+      ">"
+      (namespace)
+    ] @type) @type)

config/neovim/store/lazy-plugins/nvim-treesitter/queries/turtle/indents.scm

@@ -0,0 +1,10 @@
+[
+  (statement)
+  (blank_node_property_list)
+  (collection)
+] @indent.begin
+
+[
+  "]"
+  ")"
+] @indent.branch

config/neovim/store/lazy-plugins/nvim-treesitter/queries/turtle/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

config/neovim/store/lazy-plugins/nvim-treesitter/queries/turtle/locals.scm

@@ -0,0 +1,12 @@
+(turtle_doc) @local.scope
+
+(subject
+  [
+    (prefixed_name)
+    (iri_reference)
+  ] @local.definition.var)
+
+[
+  (prefixed_name)
+  (iri_reference)
+] @local.reference