Regenerate nvim config

config/neovim/store/lazy-plugins/nvim-treesitter/queries/ocamllex/highlights.scm

@@ -0,0 +1,70 @@
+; Allow OCaml highlighter
+(ocaml) @none
+
+; Regular expressions
+(regexp_name) @variable
+
+[
+  (eof)
+  (any)
+] @constant
+
+(character) @character
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+(character_set
+  "^" @punctuation.special)
+
+(character_range
+  "-" @punctuation.delimiter)
+
+(regexp_difference
+  "#" @operator)
+
+(regexp_repetition
+  [
+    "?"
+    "*"
+    "+"
+  ] @operator)
+
+(regexp_alternative
+  "|" @operator)
+
+; Rules
+(lexer_entry_name) @function
+
+(lexer_argument) @variable.parameter
+
+(lexer_entry
+  [
+    "="
+    "|"
+  ] @punctuation.delimiter)
+
+; keywords
+[
+  "and"
+  "as"
+  "let"
+  "parse"
+  "refill"
+  "rule"
+  "shortest"
+] @keyword
+
+; Punctuation
+[
+  "["
+  "]"
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket
+
+; Misc
+(comment) @comment @spell

config/neovim/store/lazy-plugins/nvim-treesitter/queries/ocamllex/injections.scm

@@ -0,0 +1,5 @@
+((ocaml) @injection.content
+  (#set! injection.language "ocaml"))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))