Regenerate nvim config

config/neovim/store/lazy-plugins/nvim-treesitter/queries/css/folds.scm

@@ -0,0 +1,4 @@
+[
+  (rule_set)
+  (import_statement)+
+] @fold

config/neovim/store/lazy-plugins/nvim-treesitter/queries/css/highlights.scm

@@ -0,0 +1,107 @@
+[
+  "@media"
+  "@charset"
+  "@namespace"
+  "@supports"
+  "@keyframes"
+  (at_keyword)
+] @keyword.directive
+
+"@import" @keyword.import
+
+[
+  (to)
+  (from)
+] @keyword
+
+(comment) @comment @spell
+
+(tag_name) @tag
+
+(class_name) @type
+
+(id_name) @constant
+
+[
+  (property_name)
+  (feature_name)
+] @property
+
+[
+  (nesting_selector)
+  (universal_selector)
+] @character.special
+
+(function_name) @function
+
+[
+  "~"
+  ">"
+  "+"
+  "-"
+  "*"
+  "/"
+  "="
+  "^="
+  "|="
+  "~="
+  "$="
+  "*="
+] @operator
+
+[
+  "and"
+  "or"
+  "not"
+  "only"
+] @keyword.operator
+
+(important) @keyword.modifier
+
+(attribute_selector
+  (plain_value) @string)
+
+(pseudo_element_selector
+  "::"
+  (tag_name) @attribute)
+
+(pseudo_class_selector
+  (class_name) @attribute)
+
+(attribute_name) @tag.attribute
+
+(namespace_name) @module
+
+((property_name) @variable
+  (#lua-match? @variable "^[-][-]"))
+
+((plain_value) @variable
+  (#lua-match? @variable "^[-][-]"))
+
+[
+  (string_value)
+  (color_value)
+  (unit)
+] @string
+
+(integer_value) @number
+
+(float_value) @number.float
+
+[
+  "#"
+  ","
+  "."
+  ":"
+  "::"
+  ";"
+] @punctuation.delimiter
+
+[
+  "{"
+  ")"
+  "("
+  "}"
+  "["
+  "]"
+] @punctuation.bracket

config/neovim/store/lazy-plugins/nvim-treesitter/queries/css/indents.scm

@@ -0,0 +1,11 @@
+[
+  (block)
+  (declaration)
+] @indent.begin
+
+(block
+  "}" @indent.branch)
+
+"}" @indent.dedent
+
+(comment) @indent.ignore

config/neovim/store/lazy-plugins/nvim-treesitter/queries/css/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))