Regenerate nvim config

config/neovim/store/lazy-plugins/nvim-treesitter/queries/bp/folds.scm

@@ -0,0 +1,6 @@
+[
+  (list_expression)
+  (map_expression)
+  (module)
+  (select_expression)
+] @fold

config/neovim/store/lazy-plugins/nvim-treesitter/queries/bp/highlights.scm

@@ -0,0 +1,55 @@
+(comment) @comment @spell
+
+(operator) @operator
+
+(integer_literal
+  "-" @operator)
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(boolean_literal) @boolean
+
+(integer_literal) @number
+
+[
+  (raw_string_literal)
+  (interpreted_string_literal)
+] @string
+
+(escape_sequence) @string.escape
+
+(identifier) @variable
+
+(module
+  type: (identifier) @function.call)
+
+(module
+  (property
+    field: (identifier) @variable.parameter))
+
+[
+  (unset)
+  (default)
+] @variable.builtin
+
+(condition
+  name: (identifier) @function.builtin)
+
+(map_expression
+  (property
+    field: (identifier) @property))
+
+(select_expression
+  "select" @keyword.conditional)

config/neovim/store/lazy-plugins/nvim-treesitter/queries/bp/indents.scm

@@ -0,0 +1,38 @@
+(list_expression) @indent.begin
+
+(list_expression
+  "]" @indent.branch)
+
+(map_expression) @indent.begin
+
+(map_expression
+  "}" @indent.branch)
+
+(select_expression) @indent.begin
+
+(select_expression
+  ")" @indent.branch)
+
+(select_value) @indent.begin
+
+(select_value
+  ")" @indent.branch)
+
+(select_pattern
+  "(" @indent.begin)
+
+(select_pattern
+  ")" @indent.branch)
+
+(select_cases) @indent.begin
+
+(select_cases
+  "}" @indent.branch)
+
+(module) @indent.begin
+
+(module
+  ")" @indent.branch)
+
+(module
+  "}" @indent.branch)

config/neovim/store/lazy-plugins/nvim-treesitter/queries/bp/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

config/neovim/store/lazy-plugins/nvim-treesitter/queries/bp/locals.scm

@@ -0,0 +1,12 @@
+(module
+  (property
+    field: (identifier) @local.definition.parameter))
+
+(map_expression
+  (property
+    field: (identifier) @local.definition.field))
+
+(assignment
+  left: (identifier) @local.definition.var)
+
+(identifier) @local.reference