Update generated neovim config

config/neovim/store/treesitter-parsers/queries/yang/folds.scm

@@ -0,0 +1,11 @@
+(statement
+  (statement_keyword "grouping")
+  (block) @fold)
+
+(statement
+  (statement_keyword "container")
+  (block) @fold)
+
+(statement
+  (statement_keyword "list")
+  (block) @fold)

config/neovim/store/treesitter-parsers/queries/yang/highlights.scm

@@ -0,0 +1,54 @@
+
+(comment) @comment
+
+; Module / submodule
+["module" "submodule"] @keyword
+
+; Keywords
+(statement_keyword) @keyword
+(statement_keyword "import") @include
+(extension_keyword) @function
+
+; Arguments
+(built_in_type) @type.builtin
+(number) @number
+(boolean) @boolean
+(date) @number
+(range (_ ".." @punctuation.special))
+(range (_ "|" @punctuation.special))
+(quoted_range "\"" @string.special)
+(quoted_range "'" @string.special)
+(yang_version) @constant.builtin
+(identifier) @variable
+(node_identifier) @variable
+(string) @string
+(string (escape_sequence) @string.escape)
+(unquoted_string) @string
+(keypath) @string.special
+
+; Always highlight the value of an enum statement as a string
+(enum_value) @string
+
+; Highlight XPath strings as special strings
+(statement
+  (statement_keyword ["when" "must"])
+  (argument (string) @string.special))
+(statement
+  (statement_keyword ["when" "must"])
+  (argument (string_concatenation (string) @string.special)))
+
+; Highlight pattern strings as regex
+(statement
+  (statement_keyword ["pattern"])
+  (argument (string) @string.regex))
+(statement
+  (statement_keyword ["pattern"])
+  (argument (string_concatenation (string) @string.regex)))
+
+; Punctuation
+(plus_symbol) @operator
+["{" "}"] @punctuation.bracket
+[";"] @punctuation.delimiter
+
+; Errors
+(ERROR) @error

config/neovim/store/treesitter-parsers/queries/yang/indents.scm

@@ -0,0 +1,10 @@
+(module) @indent
+(submodule) @indent
+(statement) @indent
+(extension_statement) @indent
+(statement ";" @indent_end)
+(extension_statement ";" @indent_end)
+(block "}" @indent_end @branch)
+
+((string) @aligned_indent
+ (#set! "delimiter" "\"\""))

config/neovim/store/treesitter-parsers/queries/yang/injections.scm

@@ -0,0 +1,6 @@
+(comment) @comment
+
+((statement
+  (statement_keyword "pattern")
+  (argument (string) @regex))
+ (#offset! @regex 0 1 0 -1))