Update generated neovim config

config/neovim/store/treesitter-parsers/queries/uxntal/folds.scm

@@ -0,0 +1,7 @@
+[
+  (macro)
+  (memory_execution)
+  (subroutine)
+
+  (comment)
+] @fold

config/neovim/store/treesitter-parsers/queries/uxntal/highlights.scm

@@ -0,0 +1,84 @@
+; Includes
+
+(include
+  "~" @include
+  _ @text.uri @string.special)
+
+; Variables
+
+(identifier) @variable
+
+; Macros
+
+(macro
+  "%"
+  (identifier) @function.macro)
+
+((identifier) @function.macro
+  (#lua-match? @function.macro "^[a-z]?[0-9]*[A-Z-_]+$"))
+
+(rune
+  . rune_start: (rune_char ",")
+  . (identifier) @function.call)
+
+(rune
+  . rune_start: (rune_char ";")
+  . (identifier) @function.call)
+
+((identifier) @function.call
+  (#lua-match? @function.call "^:"))
+
+; Keywords
+
+(opcode) @keyword
+
+; Labels
+
+(label
+  "@" @symbol
+  (identifier) @function)
+
+(sublabel_reference
+  (identifier) @namespace
+  "/" @punctuation.delimiter
+  (identifier) @label)
+
+; Repeats
+
+((identifier) @repeat
+  (#eq? @repeat "while"))
+
+; Literals
+
+(raw_ascii) @string
+
+(hex_literal
+  "#" @symbol
+  (hex_lit_value) @string.special)
+
+(number) @number
+
+; Punctuation
+
+[ "{" "}" ] @punctuation.bracket
+
+[ "[" "]" ] @punctuation.bracket
+
+[
+  "%"
+  "|"
+  "$"
+  ","
+  "_"
+  "."
+  "-"
+  ";"
+  "="
+  "!"
+  "?"
+  "&"
+] @punctuation.special
+
+; Comments
+
+(comment) @comment @spell

config/neovim/store/treesitter-parsers/queries/uxntal/indents.scm

@@ -0,0 +1,17 @@
+(memory_execution) @auto
+
+[
+  (subroutine)
+  (brackets)
+] @indent
+
+"}" @indent_end
+
+[ "{" "}" ] @branch
+
+[ "[" "]" ] @branch
+
+[
+  (ERROR)
+  (comment)
+] @auto

config/neovim/store/treesitter-parsers/queries/uxntal/injections.scm

@@ -0,0 +1 @@
+(comment) @comment

config/neovim/store/treesitter-parsers/queries/uxntal/locals.scm

@@ -0,0 +1,22 @@
+; Scopes
+
+[
+  (program)
+  (macro)
+  (memory_execution)
+  (subroutine)
+] @scope
+
+; References
+
+(identifier) @reference
+
+; Definitions
+
+(label
+  "@"
+  . (identifier) @definition.function)
+
+(macro
+  "%"
+  . (identifier) @definition.macro)