Update generated neovim config

config/neovim/store/treesitter-parsers/queries/udev/highlights.scm

@@ -0,0 +1,44 @@
+(match key: _ @keyword)
+(assignment key: _ @property)
+
+[
+  (system_const)
+  (run_type)
+  (import_type)
+  (attribute)
+  (kernel_param)
+  (seclabel)
+] @attribute
+
+(env_var) @constant
+
+(value) @string
+
+(pattern) @string.regexp
+
+(fmt_sub . _ @variable.builtin)
+
+(var_sub . _ @variable.builtin)
+
+[
+ "\\\""
+ (c_escape)
+] @string.escape
+
+[
+  (octal)
+  (number)
+] @number
+
+[
+  (match_op)
+  (assignment_op)
+] @operator
+
+"+" @punctuation.special
+
+[ "{" "}" ] @punctuation.bracket
+
+[ "," (linebreak) ] @punctuation.delimiter
+
+(comment) @comment

config/neovim/store/treesitter-parsers/queries/udev/injections.scm

@@ -0,0 +1,9 @@
+((match
+  key: "PROGRAM"
+  (value (content) @injection.content))
+  (#set! injection.language "bash"))
+
+((assignment
+  key: "RUN"
+  (value (content) @injection.content))
+  (#set! injection.language "bash"))

config/neovim/store/treesitter-parsers/queries/udev/tags.scm

@@ -0,0 +1,20 @@
+(assignment
+  key: "LABEL"
+  (value
+    (content) @name)) @definition.label
+
+(assignment
+  key: "GOTO"
+  (value
+    (content) @name)) @reference.label
+
+(assignment
+  key: "ENV"
+  (env_var) @name) @definition.variable
+
+(match
+  key: "ENV"
+  (env_var) @name) @reference.variable
+
+(var_sub
+  (env_var) @name) @reference.variable