Update generated neovim config

config/neovim/store/treesitter-parsers/queries/qmljs/highlights.scm

@@ -0,0 +1,60 @@
+;;; Annotations
+
+(ui_annotation
+  "@" @operator
+  type_name: [
+    (identifier) @attribute
+    (nested_identifier (identifier) @attribute)
+  ])
+
+;;; Properties
+
+(ui_object_definition_binding
+  name: [
+    (identifier) @property
+    (nested_identifier (identifier) @property)
+  ])
+
+(ui_binding
+  name: [
+    (identifier) @property
+    (nested_identifier (identifier) @property)
+  ])
+
+;; locals query appears not working unless id: <ref> isn't a parameter.
+(ui_binding
+  name: (identifier) @property
+  (#eq? @property "id")
+  value: (expression_statement (identifier) @variable.parameter))
+
+(ui_property
+  name: (identifier) @property)
+
+(ui_required
+  name: (identifier) @property)
+
+(ui_list_property_type
+  ["<" ">"] @punctuation.bracket)
+
+;;; Signals
+
+(ui_signal
+  name: (identifier) @function.signal)
+
+(ui_signal_parameter
+  (identifier) @variable.parameter)
+
+;;; Keywords
+
+[
+  "as"
+  "component"
+  "default"
+  "import"
+  "on"
+  "pragma"
+  "property"
+  "readonly"
+  "required"
+  "signal"
+] @keyword

config/neovim/store/treesitter-parsers/queries/qmljs/locals.scm

@@ -0,0 +1,6 @@
+;;; Definitions
+
+(ui_binding
+  name: (identifier) @property
+  (#eq? @property "id")
+  value: (expression_statement (identifier) @local.definition))