Update generated neovim config

config/neovim/store/treesitter-parsers/queries/puppet/folds.scm

@@ -0,0 +1,12 @@
+[
+  (block)
+  (defined_resource_type)
+  (parameter_list)
+  (attribute_type_entry)
+  (resource_declaration)
+  (selector)
+  (case_statement)
+  (hash)
+  (array)
+  (comment)
+] @fold

config/neovim/store/treesitter-parsers/queries/puppet/highlights.scm

@@ -0,0 +1,193 @@
+; Variables
+
+(identifier) @variable
+
+; Includes
+
+"include" @include
+
+(include_statement (identifier) @type)
+
+(include_statement (class_identifier (identifier) @type . ))
+
+; Keywords
+
+[
+  "class"
+  "inherits"
+  "node"
+  "type"
+  "tag"
+] @keyword
+
+[
+  "define"
+  "function"
+] @keyword.function
+
+[
+  "if"
+  "elsif"
+  "else"
+  "unless"
+  "case"
+] @conditional
+
+(default_case "default" @conditional)
+
+; Properties
+
+(attribute name: (identifier) @property)
+(attribute name: (variable (identifier) @property))
+
+; Parameters
+
+(lambda (variable (identifier) @parameter))
+
+(parameter (variable (identifier) @parameter))
+
+(function_call (identifier) @parameter)
+
+; Functions
+
+(function_declaration
+  "function" . (identifier) @function)
+
+(function_call
+  (identifier) @function.call "(")
+
+(function_call
+  (field_expression "." (identifier) @method.call) "(")
+
+(defined_resource_type
+  "define" . (identifier) @function)
+
+; Methods
+
+(function_declaration
+  "function" . (class_identifier (identifier) @method . ))
+
+(function_call
+  (class_identifier (identifier) @method.call . ))
+
+(defined_resource_type
+  "define" . (class_identifier (identifier) @method . ))
+
+; Types
+
+(type) @type
+
+(builtin_type) @type.builtin
+
+(class_definition
+  (identifier) @type)
+(class_definition
+  (class_identifier (identifier) @type . ))
+
+(class_inherits (identifier) @type)
+(class_inherits (class_identifier (identifier) @type . ))
+
+(resource_declaration
+  (identifier) @type)
+(resource_declaration
+  (class_identifier (identifier) @type . ))
+
+(node_definition (node_name (identifier) @type))
+
+((identifier) @type
+  (#lua-match? @type "^[A-Z]"))
+
+((identifier) @type.builtin
+  (#any-of? @type.builtin "Boolean" "Integer" "Float" "String" "Array" "Hash" "Regexp" "Variant" "Data" "Undef" "Default" "File"))
+
+; "Namespaces"
+
+(class_identifier . (identifier) @namespace)
+
+; Operators
+
+[
+  "or"
+  "and"
+  "in"
+] @keyword.operator
+
+[
+  "="
+  "+="
+  "->"
+  "~>"
+  "<<|"
+  "<|"
+  "|>"
+  "|>>"
+  "?"
+  ">"
+  ">="
+  "<="
+  "<"
+  "=="
+  "!="
+  "<<"
+  ">>"
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "=~"
+  "!~"
+] @operator
+
+; Punctuation
+
+[
+  "|"
+  "."
+  ","
+  ";"
+  ":"
+  "::"
+  "=>"
+] @punctuation.delimiter
+
+[ "{" "}" ] @punctuation.bracket
+
+[ "[" "]" ] @punctuation.bracket
+
+[ "(" ")" ] @punctuation.bracket
+
+(interpolation [ "${" "}" ] @punctuation.special)
+
+[
+  "$"
+  "@"
+  "@@"
+] @punctuation.special
+
+; Literals
+
+(number) @number
+
+(float) @float
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+(regex) @string.regex
+
+(boolean) @boolean
+
+[
+  (undef)
+  (default)
+] @variable.builtin
+
+; Comments
+
+(comment) @comment @spell
+
+; Errors
+
+(ERROR) @error

config/neovim/store/treesitter-parsers/queries/puppet/indents.scm

@@ -0,0 +1,30 @@
+[
+  (block)
+  (defined_resource_type)
+  (parameter_list)
+  (attribute_type_entry)
+  (resource_declaration)
+  (selector)
+  (case_statement)
+  (hash)
+  (array)
+] @indent.begin
+
+
+[
+  "}"
+  "]"
+  ")"
+] @indent.end
+
+[ "{" "}" ] @indent.branch
+
+[ "[" "]" ] @indent.branch
+
+[ "(" ")" ] @indent.branch
+
+[
+  (string)
+  (comment)
+  (ERROR)
+] @indent.auto

config/neovim/store/treesitter-parsers/queries/puppet/injections.scm

@@ -0,0 +1,2 @@
+((regex) @regex
+  (#offset! @regex 0 1 0 -1))

config/neovim/store/treesitter-parsers/queries/puppet/locals.scm

@@ -0,0 +1,46 @@
+; Scopes
+
+[
+  (block)
+  (defined_resource_type)
+  (parameter_list)
+  (attribute_type_entry)
+  (class_definition)
+  (node_definition)
+  (resource_declaration)
+  (selector)
+  (iterator_statement)
+  (case_statement)
+  (hash)
+  (array)
+] @scope
+
+; References
+
+[
+  (identifier)
+  (class_identifier)
+  (variable) 
+] @reference
+
+; Definitions
+
+(attribute [(identifier) (variable)] @definition.field)
+
+(function_declaration
+  [(identifier) (class_identifier)] @definition.function)
+
+(include_statement [(identifier) (class_identifier)] @definition.import)
+
+(parameter (variable) @definition.parameter)
+
+(class_definition
+  [(identifier) (class_identifier)] @definition.type)
+
+(node_definition
+  (node_name (identifier) @definition.type))
+
+(resource_declaration
+  [(identifier) (class_identifier)] @definition.type)
+
+(assignment . (variable) @definition.var)