Update generated neovim config

config/neovim/store/nvim-treesitter/queries/vrl/folds.scm

@@ -0,0 +1,6 @@
+[
+  (block)
+  (object)
+  (array)
+  (arguments)
+] @fold

config/neovim/store/nvim-treesitter/queries/vrl/highlights.scm

@@ -0,0 +1,108 @@
+(comment) @comment @spell
+
+(null) @constant.builtin
+
+(timestamp) @constant
+
+(closure_variables
+  (ident) @variable.parameter)
+
+(integer) @number
+
+(float) @number.float
+
+[
+  (string)
+  (raw_string)
+] @string
+
+[
+  (raw_string_escape_sequence)
+  (escape_sequence)
+  (regex_escape_sequence)
+] @string.escape
+
+(string_template
+  "{{" @punctuation.special
+  (_)
+  "}}" @punctuation.special)
+
+(regex) @string.regexp
+
+(boolean) @boolean
+
+(ident) @variable
+
+(noop) @variable.builtin
+
+(function_call
+  (ident) @function.call)
+
+; VRL queries
+(query
+  [
+    (event)
+    (metadata)
+  ] @variable.builtin)
+
+(query
+  (path
+    [
+      (field) @variable
+      (string) @string
+      (index) @number
+      "." @punctuation.delimiter
+    ]))
+
+"return" @keyword.return
+
+"abort" @keyword.exception
+
+[
+  "if"
+  "else"
+] @keyword.conditional
+
+[
+  "="
+  "=="
+  "!="
+  "|="
+  ">"
+  ">="
+  "<"
+  "<="
+  "+"
+  "-"
+  "*"
+  "/"
+  "&&"
+  "||"
+  "??"
+  "|"
+  "!"
+] @operator
+
+[
+  "->"
+  ":"
+  ";"
+  ","
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(closure_variables
+  "|" @punctuation.bracket)
+
+(function_call
+  (ident) @keyword.exception
+  "!"
+  (#any-of? @keyword.exception "assert" "assert_eq"))

config/neovim/store/nvim-treesitter/queries/vrl/indents.scm

@@ -0,0 +1,24 @@
+[
+  (block)
+  (object)
+  (array)
+  (arguments)
+] @indent.begin
+
+(block
+  "}" @indent.end)
+
+(object
+  "}" @indent.end)
+
+(array
+  "]" @indent.end)
+
+(arguments
+  ")" @indent.end)
+
+[
+  ")"
+  "]"
+  "}"
+] @indent.branch

config/neovim/store/nvim-treesitter/queries/vrl/injections.scm

@@ -0,0 +1,6 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((regex) @injection.content
+  (#offset! @injection.content 0 2 0 -1)
+  (#set! injection.language "regex"))

config/neovim/store/nvim-treesitter/queries/vrl/locals.scm

@@ -0,0 +1,16 @@
+(closure_variables
+  (ident) @local.definition.parameter)
+
+[
+  (ident)
+  (metadata)
+] @local.reference
+
+(query
+  (event) @local.reference)
+
+[
+  (block)
+  (closure)
+  (if_statement)
+] @local.scope